[VB2] ピクチャー ボックスにスクロール バーを付ける方法

概要

Visual Basic for Windows 2.0 のピクチャー ボックス コントロールはテキスト
ボックス コントロールと違い、スクロール バーが付いていません。
この資料はピクチャー ボックスを 2 つ使用することで、ピクチャー ボックス内
の図のスクロールをさせる方法について記述しています。

手順

フォーム上にピクチャー ボックス (picScrollBase) を配置し、このピクチャー
ボックスの中にもう一つのピクチャー ボックス (picScrollData) を配置します。

サンプル

  VERSION 2.00
  Begin Form frmPicScroll
     AutoRedraw      =   -1  'True
     BackColor       =   &H00C0C0C0&
     Caption         =   "スクロール バー付ピクチャー ボックス"
     Height          =   4500
     Left            =   1005
     LinkTopic       =   "Form1"
     ScaleHeight     =   275
     ScaleMode       =   3  'ピクセル
     ScaleWidth      =   355
     Top             =   1290
     Width           =   5415
     Begin HScrollBar hsbPicture
        Height          =   285
        Left            =   150
        TabIndex        =   1
        Top             =   3600
        Width           =   4575
     End
     Begin VScrollBar vsbPicture
        Height          =   3255
        Left            =   4920
        TabIndex        =   0
        Top             =   120
        Width           =   255
     End
     Begin PictureBox picScrollBase
        AutoRedraw      =   -1  'True
        BorderStyle     =   0  'なし
        Height          =   3285
        Left            =   240
        ScaleHeight     =   219
        ScaleMode       =   3  'ピクセル
        ScaleWidth      =   305
        TabIndex        =   2
        Top             =   240
        Width           =   4575
        Begin PictureBox picScrollData
           AutoRedraw      =   -1  'True
           AutoSize        =   -1  'True
           BorderStyle     =   0  'なし
           Height          =   5760
           Left            =   600
           Picture         =   PICSCROL.FRX:0000
           ScaleHeight     =   384
           ScaleMode       =   3  'ピクセル
           ScaleWidth      =   593
           TabIndex        =   3
           Top             =   600
           Width           =   8895
        End
     End
  End
  Option Explicit
  Sub Form_Load ()
      picScrollData.Top = 0
      picScrollData.Left = 0
      hsbPicture.Top = picScrollBase.Top + picScrollBase.Height
      hsbPicture.Left = picScrollBase.Left
      hsbPicture.Width = picScrollBase.Width
      hsbPicture.Max = picScrollData.Width - picScrollBase.Width
      vsbPicture.Top = picScrollBase.Top
      vsbPicture.Left = picScrollBase.Left + picScrollBase.Width
      vsbPicture.Height = picScrollBase.Height
      vsbPicture.Max = picScrollData.Height - picScrollBase.Height
      hsbPicture.Enabled = (picScrollBase.Width < picScrollData.Width)
      vsbPicture.Enabled = (picScrollBase.Height < picScrollData.Height)
  End Sub
  Sub hsbPicture_Change ()
     picScrollData.Left = -hsbPicture.Value
  End Sub
  Sub vsbPicture_Change ()
     picScrollData.Top = -vsbPicture.Value
  End Sub